Set modifiers with searches

Load script

Load the following data as an inline load in the data load editor to create the chart expression examples below.

MyTable:
Load 
Year(Date) as Year,
Date#(Date,'YYYY-MM-DD') as ISO_Date, 
Date(Date#(Date,'YYYY-MM-DD'),'M/D/YYYY') as US_Date, 
Country, Product, Amount 
Inline
[Date, Country, Product, Amount
2018-02-20, Canada, Washer, 6
2018-07-08, Germany, Anchor bolt, 10
2018-07-14, Germany, Anchor bolt, 3
2018-08-31, France, Nut, 2
2018-09-02, Czech Republic, Bolt, 1
2019-02-11, Czech Republic, Bolt, 3
2019-07-31, Czech Republic, Washer, 6
2020-03-13, France, Anchor bolt, 1
2020-07-12, Canada, Anchor bolt, 8
2020-09-16, France, Washer, 1];	

For more information about using inline loads, see Using inline loads to load data.

Example 1: Chart expressions with text searches

Create a table in a Qlik Sense sheet with the following chart expressions.

Explanation

• Dimensions:

  • Country

• Measures:

  • Sum(Amount)

    Sum Amount with no set expression.

  • Sum({<Country={"C*"}>}Amount)

    Sum Amount for all countries that start with C, such as Canada and Czech Republic.

  • Sum({<Country={"*^R*"}>}Amount)

    Sum Amount for all countries that have a word that starts with R, such as Czech Republic.

  • Sum({<Product={"*bolt*"}>}Amount)

    Sum Amount for all products that contain the string bolt, such as Bolt and Anchor bolt.

For more information about expressions, see Using expressions in visualizations.

Example 2: Chart expressions with numeric searches

Create a table in a Qlik Sense sheet with the following chart expressions.

Explanation

• Dimensions:

  • Country

• Measures:

  • Sum(Amount)

    Sum Amount with no set expression.

  • Sum({<Year={">2019"}>}Amount)

    Sum Amount for all years after 2019.

  • Sum({<ISO_Date={">=2019-07-01"}>}Amount)

    Sum Amount for all dates on or after 2019-07-01. The format of the date in the search must match the format of the field.

  • Sum({<US_Date={">=4/1/2018<=12/31/2018"}>}Amount)

    Sum Amount for all dates from 4/1/2018 to 12/31/2018, including the start and end dates. The format of the dates in the search must match the format of the field.

Example 3: Chart expressions with expression searches

Create a table in a Qlik Sense sheet with the following chart expressions.

Explanation

• Dimensions:

  • Country

• Measures:

  • Sum(Amount)

    Sum Amount with no set expression.

  • Sum({<Country={"=Sum(Amount)>10"}>}Amount)

    Sum Amount for all countries that have an aggregated sum of Amount greater than 10.

  • Sum({<Country={"=Count(distinct Product)=1"}>}Amount)

    Sum Amount for all countries that are associated with exactly one distinct product.

  • Sum({<Product={"=Count(Amount)>3"}>}Amount)

    Sum Amount for all countries that have more than three transactions in the data.